home *** CD-ROM | disk | FTP | other *** search
/ Mac Magazin/MacEasy 32 / Mac Magazin and MacEasy Magazine CD - Issue 32.iso / Grafik & Text / OzTeX3.0 / Metafont / Inputs / ec / exidigit.mf < prev    next >
Text File  |  1997-03-16  |  12KB  |  279 lines
  1. % exidigit.mf
  2. %
  3. % (c) Copyright 1995, 1996, 1997 J"org Knappen
  4. % (c) Copyright 1990, 1992 Norbert Schwarz
  5. %
  6. % This file is part of ecfonts version 1.0
  7. %
  8. % Please read the files 00readme.txt, 00inst.txt, 00error.txt, and
  9. % copyrite.txt for further information
  10. %
  11. % You find some documentation in ecdoc.tex (needs LaTeX2e)
  12. %
  13. % Content:
  14. %
  15. %   italic numerals
  16.  
  17. version_check(1,0);  % |version_check| was introduced in dc1.3
  18.  
  19. % All digits have the same width
  20.  
  21. font_digit_width 9u#;
  22.  
  23. ecchar "Italic numeral 0";
  24. beginchar("0",9u#,fig_height#,0);
  25. italcorr fig_height#*slant-.5u#;
  26. adjust_fit(0,0);
  27. penpos1(vair,90); penpos3(vair,-90); penpos2(curve,180); penpos4(curve,0);
  28. if not monospace: interim superness:=sqrt(more_super*hein_super); fi
  29. x2r=hround(1.5u-.5curve); x4r=w-x2r; x1=x3=.5w;
  30. y1r=h+o; y3r=-o; y2=y4=.5h-vair_corr; y2l:=y4l:=.52h;
  31. penstroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
  32.  & pulled_arc.e(3,4) & pulled_arc.e(4,1) & cycle;  % bowl
  33. penlabels(1,2,3,4); endchar;
  34.  
  35. ecchar "Italic numeral 1";
  36. beginchar("1",9u#,fig_height#,0);
  37. italcorr fig_height#*slant-.5u#;
  38. adjust_fit(0,0); pickup tiny.nib;
  39. numeric light_stem; light_stem=hround .4[stem',cap_stem'];
  40. pos1(light_stem,0); pos2(light_stem,0);
  41. lft x1l=lft x2l=hround(.5(w+.5u)-.5cap_stem'); top y1=h+apex_o; bot y2=0;
  42. filldraw stroke z1e--z2e;  % stem
  43. if one_serif: dish_serif(2,1,a,1/3,min(2.25u,lft x2l-1.5u),
  44.   b,1/3,min(2.25u,w-1.25u-rt x2r)); fi % serif
  45. pickup crisp.nib; pos3(slab,-90); pos4(bar,-90);
  46. top y3l=h+apex_o; top y4l=.8h+apex_o;
  47. lft x4=max(1.25u,tiny.lft x1l-2.35u); tiny.rt x1r=lft x3+.25[tiny,hair];
  48. erase fill z3l{x4l-x3l,3(y4l-y3l)}...z4l{left}
  49.  --(x4l,h+apex_o+1)--(x3l,h+apex_o+1)--cycle; % erase excess at top
  50. filldraw stroke z3e{x4e-x3e,3(y4e-y3e)}..{left}z4e;  % point
  51. penlabels(1,2,3,4); endchar;
  52.  
  53. ecchar "Italic numeral 2";
  54. beginchar("2",9u#,fig_height#,0);
  55. italcorr fig_height#*slant-.5u#;
  56. adjust_fit(0,0); pickup fine.nib;
  57. pos1(vair,45); pos2(vair,0); pos3(vair,-90); pos4(hair,-180);
  58. pos5(vair,-270); pos6(curve,-360); pos7(hair,-405); pos8(hair,-360);
  59. x1=x2-.5u; rt x2r=hround(3.5u+.5vair);
  60. x3=.6[x2,x4]; lft x4r=hround(u-.5hair);
  61. x5=x7=.5w-.5u; rt x6r=hround(w-u); lft x8l=hround(1.5u-.5hair);
  62. y1=.5[x_height,h]; y2=1/3[y1,y3]; y4=x_height; bot y3r=vround .78y4;
  63. top y5r=h+o; y6=.5[y5,y7]; y7=.52y4; bot y8=-o;
  64. filldraw stroke if not hefty:z1e{2(x2-x1),y2-y1}...{down}z2e...{left}z3e...fi
  65.  z4e{up}...pulled_arc.e(5,6)
  66.  ...z7e{2(x7-x6),y7-y6}...{down}z8e; % main stroke
  67. pos9(vair,-90); pos10(vstem+curve-stem,-90); pos11(hair,0);
  68. x9=w-x10=2.5u; rt x11r=hround(w-.5u+.5hair);
  69. y9=.25[y10,y7]; bot y10r=-o; y11=.38x_height;
  70. filldraw stroke z8e{up}...z9e{right}..{right}z10e...{up}z11e;  % bar
  71. penlabels(1,2,3,4,5,6,7,8,9,10,11); endchar;
  72.  
  73. ecchar "Italic numeral 3";
  74. beginchar("3",9u#,fig_height#,0);
  75. italcorr fig_height#*slant-.5u#;
  76. adjust_fit(0,0); pickup fine.nib;
  77. pos1(vair,45); pos2(vair,0); pos3(vair,-90); pos4(hair,-180);
  78. pos5(vair,-270); pos6(stem,-360); pos7(bar,-450); pos8(bar,-450);
  79. x1=x2-.5u; rt x2r=hround(3.5u+.5vair); x3=.5[x2,x4]; lft x4r=hround u;
  80. x5=x7=.5w; rt x6r=hround(w-u); x8=x7-u;
  81. y1=.5[x_height,h]; y2=.5[y1,y3]; y7=y8=.52h; bot y3r=vround 1/4[y7,h];
  82. y4=1/3[y3,y5]; top y5r=h+o; y6=.5[y5,y7];
  83. filldraw stroke if not hefty: z1e{2(x2-x1),y2-y1}...{down}z2e...{left}z3e...fi
  84.  z4e{up}...pulled_arc.e(5,6) & pulled_arc.e(6,7)..z8e; % upper arc
  85. pos7'(vair,90); z7'l=z7r;
  86. pos9(curve,0); pos10(vair,-90); pos11(hair,-180); pos12(flare,-180);
  87. rt x9r=hround(w-u); x10=.5w-.5u; lft x11r=hround .75u;
  88. y9=.25h; bot y10r=-o; y11=1/3x_height; bulb(10,11,12);  % bulb
  89. filldraw stroke pulled_arc.e(7',9) & pulled_arc.e(9,10);  % lower arc
  90. penlabels(1,2,3,4,5,6,7,8,9,10,11,12); endchar;
  91.  
  92. ecchar "Italic numeral 4";
  93. beginchar("4",9u#,fig_height#,desc_depth#);
  94. italcorr fig_height#*slant-.5u#;
  95. adjust_fit(0,0); pickup fine.nib;
  96. pos1(stem,0); pos6(stem,0); pos7(stem,0);
  97. pos2(bar,-45); pos3(bar,-90); pos4(bar,-90); pos5(bar,-45);
  98. rt x1r=hround(.5w+.5u+.5stem); lft x2l=hround .25u;
  99. x3=2.75u; x4=w-2u; rt x5r=hround(w-.25u);
  100. rt x6r=rt x7r=hround(2/3w+.5stem);
  101. y1+.5stem=h+o; bot y2r=0; bot y3r=vround(.08h-.5bar);
  102. bot y4r=vround-.5bar; bot y5r=vround(.03h-.5bar);
  103. y6+.5stem=bar_height; y7-.5stem=-d;
  104. filldraw circ_stroke z1e{down}...{3(x2-x1),y2-y1}z2e;  % diagonal
  105. filldraw stroke z2e{z1-z2}...z3e{right}..{right}z4e
  106.  ...{x5-x4,2(y5-y4)}z5e;  % bar
  107. filldraw z6l---z7l..z7r---z6r..cycle;  % stem
  108. penlabels(1,2,3,4,5,6,7); endchar;
  109.  
  110. ecchar "Italic numeral 5";
  111. beginchar("5",9u#,fig_height#,0);
  112. italcorr fig_height#*slant-.5u#;
  113. adjust_fit(0,0);
  114. numeric bot_thickness,light_hair;
  115. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  116. light_hair=hround(cap_hair if hefty: -\\2stem_corr fi);
  117. pickup tiny.nib; pos5(vair,180); pos6(vair,90);
  118. bot y5=vround(.53h-vair); top y6r=max(vround .61803h+o,top y6r+y5+eps-y6l);
  119. pos3(light_hair,0); pos4(light_hair,0);
  120. lft x3l=max(1.35u,2.1u-.5light_hair); x3=x4=x5; y4=y5;
  121. top y3=h if not hefty: +\\o fi;
  122. filldraw stroke z3e--z4e;  % thin stem
  123. penpos7(cap_stem-fine,0); penpos8(bot_thickness-fine,-90);
  124. fine.rt x7r=hround(w-.9u); x8=.5[u,x7]; x6=.5[x5,x7];
  125. erase fill z5--bot z5--(x6,bot y5)--z6{left}
  126.  ..tension .9 and 1..{x5-x6,3(y5-y6)}cycle; % erase excess in middle
  127. filldraw stroke z6e{left}..tension .9 and 1..{x5-x6,3(y5-y6)}z5e;  % link
  128. pickup fine.nib; pos6'(vair,90); z6'=z6;
  129. y7=.5[y6,y8]; bot y8r=-o;
  130. filldraw stroke pulled_arc.e(6',7) & pulled_arc.e(7,8);  % bowl
  131. if serifs: pos9(hair,-180); y9=.5y5; lft x9r=hround .9u;
  132.  pos10(flare+1/3(cap_stem-stem),-180); bulb(8,9,10);  % bulb
  133. else: pos9(3/7[bot_thickness,flare],angle(-7u,-h));
  134.  lft x9r=hround(tiny.lft x3l-.75u); bot y9r=vround .15h-o;
  135.  x9l:=good.x x9l; y9l:=good.y y9l;
  136.  filldraw stroke term.e(8,9,left,1,4); fi  % terminal
  137. if hefty: pickup crisp.nib; pos1(slab,90); pos2(hair,0);
  138.  top y1r=h; x1=x4; rt x2r=hround(w-1.5u); y2=y1l-eps;
  139.  arm(1,2,a,0,0);  % arm
  140. else: numeric flag_breadth; flag_breadth=7/8[vair,cap_curve];
  141.  pos1(flag_breadth,90); pos2(flag_breadth,60);
  142.  pos0(vair,90); top y1r=tiny.top y3; top y2r=vround .95h+o; y0r=y1r;
  143.  lft x1=tiny.lft x3l; x2r=.5[x1,x0]; rt x0=hround(w-1.6u);
  144.  erase fill top z1r--z1r...{right}z2r
  145.   --(x2r,top y1r)--cycle; % erase excess at top
  146.  filldraw stroke z1e...{right}z2e...z0e; fi  % flag
  147. penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  148.  
  149. ecchar "Italic numeral 6";
  150. beginchar("6",9u#,fig_height#,0);
  151. italcorr fig_height#*slant-.5u#;
  152. adjust_fit(0,0);
  153. numeric top_thickness,bot_thickness,side_thickness,pull;
  154. top_thickness=max(fine.breadth,vround(slab-2vair_corr));
  155. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  156. side_thickness=max(fine.breadth,hround 1/3[curve,cap_curve]);
  157. pull=min(.25,1.5superpull);
  158. pickup fine.nib; pos2(top_thickness,-270);
  159. pos3(side_thickness,-180); pos4(bot_thickness,-90);
  160. pos5(side_thickness,0); pos6(vair,90);
  161. lft x3r=w-rt x5r=hround max(.75u,1.5u-.5side_thickness);
  162. x4=x6-.1u=x2-u=.5w;
  163. top y2r=h+o; y3=.5[y2,y4]; bot y4r=-o;
  164. y5=.5[y4,y6]; top y6=vround 5/8h+o;
  165. path p; p=pulled_super_arc.l(3,4)(pull);
  166. numeric t; t=xpart(p intersectiontimes((x3r,y5)--(x4,y5)));
  167. pos7(thin_join,180); z7l=point t of p;
  168. (x,y6r)=whatever[z7l,z6l]; x6r:=min(x,.5[x5r,x6]);
  169. filldraw stroke pulled_super_arc.e(2,3)(pull)
  170.  & {{interim superness:=more_super; pulled_super_arc.e(3,4)(pull)}}
  171.  & {{less_tense; pulled_super_arc.e(4,5)(pull) & pulled_super_arc.e(5,6)(pull)}}
  172.  & z6e{left}...{direction t of p}z7e;  % arc and bowl
  173. if serifs: pos1(hair,-360); pos0(flare,-360);
  174.  rt x0r=max(rt x2+eps,hround(w-1.2u));
  175.  y0=vround min(.9h-.5flare,.85h+.5flare)+o;
  176.  {{less_tense; bulb(2,1,0)}};  % arc and bulb
  177. else: pos1(vround .1[top_thickness,flare],90);
  178.  top y1r=vround .97h+o; rt x1=hround(x5-.5);
  179.  filldraw stroke term.e(2,1,right,.9,4); fi  % terminal
  180. penlabels(0,1,2,3,4,5,6,7); endchar;
  181.  
  182. ecchar "Italic numeral 7";
  183. beginchar("7",9u#,fig_height#,0);
  184. italcorr fig_height#*slant-.5u#;
  185. adjust_fit(0,0); pickup fine.nib;
  186. numeric fat_curve; fat_curve=1.4[stem,curve];
  187. pos1(hair,0); pos2(hair,0); pos3(vstem+curve-stem,-90);
  188. pos4(vair,-90); pos5(hair,0); pos6(fat_curve,0);
  189. top y1=h+o; y2=x_height; y3l=y5=y1;
  190. bot y4r=vround(.5[y2,h]-.5vair); y6-.5fat_curve=-o;
  191. lft x2l=hround(.5u-.5hair); x3=.5w-.5u; x4=2/3w;
  192. rt x5r=hround(w-.75u+.5hair); rt x6r=hround(.5w+u+.5fat_curve);
  193. z1=z2+whatever*(z5-z6); filldraw stroke z1e--z2e;  % serif
  194. filldraw stroke z2e{z1-z2}...z3e{right}..{right}z4e
  195.  ...{2(x5-x6),y5-y6}z5e;  % bar
  196. filldraw circ_stroke z6e{up}...{2(x5-x6),y5-y6}z5e;  % diagonal
  197. penlabels(1,2,3,4,5,6); endchar;
  198.  
  199. ecchar "Italic numeral 8";
  200. beginchar("8",9u#,fig_height#,0);
  201. italcorr fig_height#*slant-.5u#;
  202. adjust_fit(0,0);
  203. numeric top_thickness,mid_thickness,bot_thickness,upper_side,lower_side,theta;
  204. top_thickness=max(fine.breadth,vround(slab-2vair_corr));
  205. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  206. x0=.5w; y0=.54h;
  207. if hefty: mid_thickness=vround 2/3vair; upper_side=hround(stem-3stem_corr);
  208.  lower_side=hround min(.5[curve,cap_curve]-stem_corr,upper_side+.25u);
  209.  penpos1(top_thickness,90); penpos2(upper_side,180);
  210.  penpos3(mid_thickness,270); penpos8(upper_side,360);
  211.  penpos4(mid_thickness,90); penpos7(lower_side,180);
  212.  penpos6(bot_thickness,270); penpos5(lower_side,360);
  213.  penpos0(vair,90); z3l=z0r; z4l=z0l;
  214.  x1=x6=.5w; x2r=w-x8r=hround u; x7r=w-x5r=hround .75u;
  215.  top y1r=h+o; bot y6r=-o; y2=y8=.5[y1l,y3l]; y7=y5=.5[y4l,y6l];
  216.  filldraw stroke pulled_arc.e(1,2)
  217.   & pulled_arc.e(2,3);  % left half of upper bowl
  218.  filldraw stroke pulled_arc.e(4,5)
  219.   & pulled_arc.e(5,6);  % right half of lower bowl
  220.  filldraw stroke pulled_arc.e(6,7)
  221.   & pulled_arc.e(7,4);  % left half of lower bowl
  222.  filldraw stroke pulled_arc.e(3,8)
  223.   & pulled_arc.e(8,1);  % right half of upper bowl
  224. else: pickup fine.nib; theta=90-angle(18u,h); slope:=-h/18u;
  225.  upper_side=max(fine.breadth,hround(.5[hair,stem]-stem_corr));
  226.  lower_side=hround(.5[hair,stem]+stem_corr);
  227.  if lower_side>1.2upper_side: upper_side:=lower_side; fi
  228.  pos1(top_thickness,-90); pos6(bot_thickness,-90);
  229.  x1=x6=.5w; top y1l=h+o; bot y6r=-o; pos0(cap_stem,theta);
  230.  lft x2l=w-rt x8l=hround 1.25u; lft x7r=w-rt x5r=hround .75u;
  231.  x2r-x2l=upper_side-fine; x5r-x5l=lower_side-fine;
  232.  ellipse_set(1l,2l,3l,0l); ellipse_set(1r,2r,3r,0r);
  233.  ellipse_set(6l,5l,4l,0l); ellipse_set(6r,5r,4r,0r);
  234.  numeric tau; tau=max(.8,.20710678/(superness-.5));
  235.  filldraw stroke z1e{left}..tension atleast tau..z2e{down}
  236.   ..z3e---z4e..z5e{down}..tension atleast tau..z6e{left};  % S stroke
  237.  pos7(lower_side,180); pos8(upper_side,180);
  238.  y7=.5[y5l,y5r]; y8=.5[y2l,y2r]; pos9(vair,90); z9=z0;
  239.  filldraw stroke z1e{right}..tension atleast tau..z8e{down}
  240.   ..tension atleast tau and atleast 1..{-18u,-.618h}z9e; % upper right stroke
  241.  filldraw stroke z6e{left}..tension atleast tau..z7e{up}
  242.   ..tension atleast tau and atleast 1..{18u,.5h}z9e; fi % lower left stroke
  243. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  244.  
  245. ecchar "Italic numeral 9";
  246. beginchar("9",9u#,fig_height#,0);
  247. italcorr fig_height#*slant-.5u#;
  248. adjust_fit(0,0);
  249. numeric top_thickness,bot_thickness,side_thickness,pull;
  250. top_thickness=max(fine.breadth,vround(slab-2vair_corr));
  251. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  252. side_thickness=max(fine.breadth,hround 1/3[curve,cap_curve]);
  253. pull=min(.25,1.5superpull);
  254. pickup fine.nib; pos2(bot_thickness,-90);
  255. pos3(side_thickness,0); pos4(top_thickness,90);
  256. pos5(side_thickness,180); pos6(vair,270);
  257. w-rt x3r=lft x5r=hround max(.75u,1.5u-.5side_thickness);
  258. x4-.1u=x6+.1u=x2+.75u=.5w;
  259. bot y2r=-o; y3=.5[y2,y4]; top y4r=h+o;
  260. y5=.5[y4,y6]; bot y6=vround 3/8h-o;
  261. path p; p=pulled_super_arc.l(3,4)(pull);
  262. numeric t; t=xpart(p intersectiontimes((x3r,y5)--(x4,y5)));
  263. pos7(thin_join,360); z7l=point t of p;
  264. (x,y6r)=whatever[z7l,z6l]; x6r:=max(x,.5[x5r,x6]);
  265. filldraw stroke pulled_super_arc.e(2,3)(pull)
  266.  & {{interim superness:=more_super; pulled_super_arc.e(3,4)(pull)}}
  267.  & {{less_tense; pulled_super_arc.e(4,5)(pull) & pulled_super_arc.e(5,6)(pull)}}
  268.  & z6e{right}...{direction t of p}z7e;  % arc and bowl
  269. if serifs: pos1(hair,-180); pos0(flare,-180);
  270.  lft x0r=min(lft x2-eps,hround 1.2u);
  271.  y0=vround max(.1h+.5flare,.15h-.5flare)-o;
  272.  {{less_tense; bulb(2,1,0)}};  % arc and bulb
  273. else: pos1(.1[bot_thickness,flare],-120);
  274.  bot y1r=vround .07h-o; lft x1r=hround 1.3u;
  275.  filldraw stroke term.e(2,1,left,.9,4); fi  % terminal
  276. penlabels(0,1,2,3,4,5,6,7); endchar;
  277.  
  278. endinput;
  279.